mirror of
https://github.com/neoStudiosLCE/neoLegacy.git
synced 2026-07-19 03:17:15 +00:00
42a582fb9f
Adds the FourKit .NET 10 plugin host as a second dedicated server
build flavour alongside the existing vanilla server. Both flavours
build from the same source tree, with FourKit gated by the
MINECRAFT_SERVER_FOURKIT_BUILD preprocessor define.
Build layout:
Minecraft.Server vanilla, no plugin support, no .NET dep
Minecraft.Server.FourKit FourKit-enabled, ships with bundled
.NET 10 self-contained runtime in runtime/
and an empty plugins/ folder
Both produce a Minecraft.Server.exe in their own per-target output
dir. The variant identity lives in the directory name, not the
binary name, so either flavour can be shipped as a drop-in.
Native bridge (Minecraft.Server/FourKit*.{cpp,h}):
* FourKitRuntime: hosts CoreCLR via hostfxr's command-line init API
(the runtime-config API does not support self-contained components)
* FourKitBridge: ~50 Fire* event entry points, with inline no-op
stubs for the standalone build so gameplay code can call them
unconditionally
* FourKitNatives: ~80 native callbacks the managed side invokes
for player/world/inventory mutations
* FourKitMappers: type and enum mapping helpers
Managed plugin host (Minecraft.Server.FourKit/):
* Bukkit-style API: Player, World, Block, Inventory, Command,
Listener, EventHandler attribute, ~54 event classes
* PluginLoader with per-plugin AssemblyLoadContext
* FourKitHost as the [UnmanagedCallersOnly] entry point table
* Runtime resolves plugins relative to the host process so they
always live next to Minecraft.Server.exe regardless of where the
managed assembly itself is loaded from
Engine hooks (Minecraft.Client/, Minecraft.World/):
* Player lifecycle (PreLogin, Login, Join, Quit, Kick, Move,
Teleport, Portal, Death) wired into PendingConnection and
PlayerConnection without disturbing the cipher handshake or
identity-token security flow
* Inventory open/click/drop hooks across every container menu type
* Block place/break/grow/burn/spread/from-to hooks across the
full tile family
* Bed enter/leave, sign change, entity damage/death, ender pearl
teleport hooks
Regression fixes preserved while applying donor diffs:
* ServerPlayer::die() retains the LCE-Revelations hardcore branch
(setGameMode(ADVENTURE) + banPlayerForHardcoreDeath) in both the
FourKit and non-FourKit code paths
* ServerLevel::entityAdded() retains the sub-entity ID reassignment
loop required by the client's handleAddMob offset, fixing Ender
Dragon and Wither boss multi-part hit detection
* LivingEntity::travel() retains the raw Player* cast and the
cached frictionTile, both Revelations perf wins that the donor
silently reverted
* ServerLogger.cpp keeps the file-logging code donor stripped
* PlayerList.cpp end portal transition fix and UIScene_EndPoem
bounds-check are intact
Build system:
* Top-level CMakeLists.txt adds the Minecraft.Server.FourKit
subdirectory and pulls in the new shared cmake/ServerTarget.cmake
helper
* Minecraft.Server/cmake/sources/Common.cmake is now location
independent (uses CMAKE_CURRENT_LIST_DIR) so the source list
can be consumed from either server target's CMakeLists.txt
* The seven FourKit*.cpp/h files live in their own
_MINECRAFT_SERVER_COMMON_SERVER_FOURKIT variable so the
standalone target omits them
* configure-time .NET 10 SDK check fails fast with a clear
download link if the SDK is missing
* global.json pins the SDK to 10.0.100 with latestFeature
rollforward
Sample plugin (samples/HelloPlugin/) demonstrates the loader and
the PlayerJoinEvent listener pattern.
CI:
* nightly.yml builds both server flavours, ships
LCE-Revelations-Server-Win64.zip and
LCE-Revelations-Server-Win64-FourKit.zip, attests both, and
updates release notes for the dual-flavour layout
* pull-request.yml pulls in actions/setup-dotnet so the FourKit
publish step works in PR validation
* All zip artifacts and the client zip are renamed from
LCREWindows64 to LCE-Revelations-{Client,Server}-Win64
Documentation:
* COMPILE.md gets a VS 2022 quick start, .NET 10 prereq section,
server flavours explanation, and a troubleshooting section
* docs/FOURKIT_PORT_RECON.md captures the file-by-file recon that
drove the port
* docs/FOURKIT_PARITY.md is the canonical reference for which
events FourKit fires
Docker:
* docker-compose.dedicated-server.yml MC_RUNTIME_DIR default points
at the vanilla CMake output. The FourKit Docker image is
intentionally NOT shipped yet because hosting .NET 10 self
contained inside Wine has not been smoke-tested
120 lines
3.3 KiB
CMake
120 lines
3.3 KiB
CMake
cmake_minimum_required(VERSION 3.24)
|
|
|
|
project(MinecraftConsoles LANGUAGES C CXX RC ASM_MASM)
|
|
set(CMAKE_CXX_STANDARD 17)
|
|
set(CMAKE_CXX_STANDARD_REQUIRED ON)
|
|
set(CMAKE_CXX_EXTENSIONS OFF)
|
|
|
|
if(NOT WIN32)
|
|
message(FATAL_ERROR "This CMake build currently supports Windows only.")
|
|
endif()
|
|
|
|
if(NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
|
|
message(FATAL_ERROR "Use a 64-bit generator/toolchain (x64).")
|
|
endif()
|
|
|
|
set(CMAKE_CONFIGURATION_TYPES
|
|
"Debug"
|
|
"Release"
|
|
CACHE STRING "" FORCE
|
|
)
|
|
set(CMAKE_MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")
|
|
|
|
function(configure_compiler_target target)
|
|
# MSVC and compatible compilers (like Clang-cl)
|
|
if (MSVC)
|
|
target_compile_options(${target} PRIVATE
|
|
$<$<AND:$<CONFIG:Debug>,$<COMPILE_LANGUAGE:C,CXX>>:/W3>
|
|
$<$<AND:$<CONFIG:Release>,$<COMPILE_LANGUAGE:C,CXX>>:/W0>
|
|
$<$<COMPILE_LANGUAGE:C,CXX>:/MP>
|
|
$<$<COMPILE_LANGUAGE:C,CXX>:/FS>
|
|
$<$<COMPILE_LANGUAGE:C,CXX>:/GS>
|
|
$<$<COMPILE_LANGUAGE:CXX>:/EHsc>
|
|
$<$<COMPILE_LANGUAGE:CXX>:/GR>
|
|
$<$<AND:$<CONFIG:Debug>,$<COMPILE_LANGUAGE:C,CXX>>:/Od>
|
|
$<$<AND:$<CONFIG:Release>,$<COMPILE_LANGUAGE:C,CXX>>:/O2 /Oi /GT /GF>
|
|
)
|
|
endif()
|
|
|
|
# MSVC
|
|
if(CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
|
|
target_compile_options(${target} PRIVATE
|
|
$<$<AND:$<CONFIG:Release>,$<COMPILE_LANGUAGE:C,CXX>>:/GL>
|
|
)
|
|
target_link_options(${target} PRIVATE
|
|
$<$<CONFIG:Release>:/LTCG:incremental>
|
|
)
|
|
endif()
|
|
|
|
# Clang
|
|
if(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
|
|
target_compile_options(${target} PRIVATE
|
|
$<$<AND:$<CONFIG:Debug>,$<COMPILE_LANGUAGE:C,CXX>>:-O0 -Wall>
|
|
$<$<AND:$<CONFIG:Release>,$<COMPILE_LANGUAGE:C,CXX>>:-O2 -w -flto>
|
|
)
|
|
target_link_options(${target} PRIVATE
|
|
$<$<CONFIG:Release>:-flto>
|
|
)
|
|
endif()
|
|
endfunction()
|
|
|
|
|
|
# ---
|
|
# Configuration
|
|
# ---
|
|
set(MINECRAFT_SHARED_DEFINES
|
|
_LARGE_WORLDS
|
|
_DEBUG_MENUS_ENABLED
|
|
$<$<CONFIG:Debug>:_DEBUG>
|
|
_CRT_NON_CONFORMING_SWPRINTFS
|
|
_CRT_SECURE_NO_WARNINGS
|
|
_HAS_STD_BYTE=0
|
|
)
|
|
|
|
# Add platform-specific defines
|
|
if(PLATFORM_NAME STREQUAL "Windows64")
|
|
list(APPEND MINECRAFT_SHARED_DEFINES _WINDOWS64)
|
|
set(IGGY_LIBS iggy_w64.lib)
|
|
endif()
|
|
list(APPEND MINECRAFT_SHARED_DEFINES ${PLATFORM_DEFINES})
|
|
|
|
# ---
|
|
# Sources
|
|
# ---
|
|
add_subdirectory(Minecraft.World)
|
|
add_subdirectory(Minecraft.Client)
|
|
if(PLATFORM_NAME STREQUAL "Windows64") # Server is only supported on Windows for now
|
|
add_subdirectory(Minecraft.Server.FourKit)
|
|
add_subdirectory(Minecraft.Server)
|
|
endif()
|
|
|
|
# ---
|
|
# Build versioning
|
|
# ---
|
|
set(BUILDVER_SCRIPT "${CMAKE_CURRENT_SOURCE_DIR}/cmake/GenerateBuildVer.cmake")
|
|
set(BUILDVER_OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/generated/Common/BuildVer.h")
|
|
|
|
add_custom_target(GenerateBuildVer
|
|
COMMAND ${CMAKE_COMMAND}
|
|
"-DOUTPUT_FILE=${BUILDVER_OUTPUT}"
|
|
-P "${BUILDVER_SCRIPT}"
|
|
COMMENT "Generating BuildVer.h..."
|
|
VERBATIM
|
|
)
|
|
|
|
add_dependencies(Minecraft.World GenerateBuildVer)
|
|
add_dependencies(Minecraft.Client GenerateBuildVer)
|
|
if(PLATFORM_NAME STREQUAL "Windows64")
|
|
add_dependencies(Minecraft.Server GenerateBuildVer)
|
|
endif()
|
|
|
|
# ---
|
|
# Project organisation
|
|
# ---
|
|
# Set the startup project for Visual Studio
|
|
set_property(DIRECTORY PROPERTY VS_STARTUP_PROJECT Minecraft.Client)
|
|
|
|
# Setup folders for Visual Studio, just hides the build targets under a sub folder
|
|
set_property(GLOBAL PROPERTY USE_FOLDERS ON)
|
|
set_property(TARGET GenerateBuildVer PROPERTY FOLDER "Build")
|