mirror of
https://github.com/smartcmd/MinecraftConsoles.git
synced 2026-10-22 19:22:04 +00:00
4f2352361a
The old Windows64 port had no real player identity — it used hardcoded fake XUIDs, so anyone could impersonate anyone. This replaces that with proper auth supporting Mojang, Ely.by, and offline accounts. MCAuth library (new, MCAuth/): Mojang auth via MSA device code flow (XBL, SISU, MC services), Ely.by via Yggdrasil with 2FA, offline UUID generation matching Java Edition (MD5 v3 from "OfflinePlayer:<name>"). Multi-account manager with background token refresh, per-slot sessions, and on-disk token persistence. Server-side session verification via Mojang/Ely.by hasJoined API. Skin fetching and PNG validation from texture servers. Network protocol (version bumped to 80): Three new packets (AuthScheme, AuthResponse, AuthResult) implement a server-driven auth handshake before login completes. Player identity migrated from 64-bit XUID to 128-bit GameUUID backed by two uint64 fields (hi/lo). readPlayerUID/writePlayerUID now serialize 16 bytes on the wire. Old and new clients cannot connect to each other — version mismatch is rejected at PreLogin. Save migration: Map data mappings auto-migrate from old format: the old 64-bit XUID is placed in hi, lo is set to 0 as a sentinel. On first access by the real player, the sentinel entry is upgraded in-place to the full 128-bit UUID. Format detection is by file size (2080, 2112, or 4160 bytes). Player .dat filenames inside saveData.ms change from decimal XUID to dashed UUID — old saves need manual entry renaming in the archive. UI: NativeUIRenderer: immediate-mode drawing system (quads, text, 9-slice panels, scrollbars, focus lists) for rendering auth screens without Flash/Scaleform. UIScene_MSAuth handles device code display, Ely.by credential input with 2FA, per-account skin head preview, and multi-account add/remove/switch. Server: online-mode and auth-provider (mojang/elyby) in server.properties. Whitelist and ban checks validate against the server-verified UUID. Incompatible auth scheme logs which provider the server expects vs what the client is using. Also fixes a pre-existing exploit where any client could send a DebugOptionsPacket to grant themselves CraftAnything and other debug privileges on any server — now requires OP status server-side.
53 lines
1.5 KiB
CMake
53 lines
1.5 KiB
CMake
# Cross-platform single file copy using fast native tools
|
||
#
|
||
# Required:
|
||
# COPY_SOURCE – pipe-separated list of source file paths
|
||
# COPY_DEST – destination directory
|
||
|
||
cmake_policy(SET CMP0057 NEW)
|
||
|
||
if(NOT COPY_SOURCE OR NOT COPY_DEST)
|
||
message(FATAL_ERROR "COPY_SOURCE and COPY_DEST must be set.")
|
||
endif()
|
||
|
||
string(REPLACE "|" ";" COPY_SOURCE "${COPY_SOURCE}")
|
||
|
||
if(CMAKE_HOST_WIN32)
|
||
# Group files by parent directory so we can batch them into single robocopy calls
|
||
set(dir_file_map "")
|
||
set(unique_dirs "")
|
||
|
||
foreach(filepath IN LISTS COPY_SOURCE)
|
||
get_filename_component(dir "${filepath}" DIRECTORY)
|
||
get_filename_component(name "${filepath}" NAME)
|
||
|
||
if(NOT dir IN_LIST unique_dirs)
|
||
list(APPEND unique_dirs "${dir}")
|
||
endif()
|
||
|
||
list(APPEND "FILES_IN_${dir}" "${name}")
|
||
endforeach()
|
||
|
||
foreach(dir IN LISTS unique_dirs)
|
||
execute_process(
|
||
COMMAND robocopy.exe "${dir}" "${COPY_DEST}" ${FILES_IN_${dir}} /MT /R:0 /W:0 /NP
|
||
RESULT_VARIABLE rc
|
||
)
|
||
|
||
if(rc GREATER 7) # Allows for "files copied" and "no files copied" cases, but treats actual errors as failures
|
||
message(FATAL_ERROR "robocopy failed (exit code ${rc})")
|
||
endif()
|
||
endforeach()
|
||
|
||
elseif(CMAKE_HOST_UNIX)
|
||
execute_process(
|
||
COMMAND rsync -av ${COPY_SOURCE} "${COPY_DEST}/"
|
||
RESULT_VARIABLE rs
|
||
)
|
||
|
||
if(rs GREATER 0) # Any non-zero exit code indicates an error
|
||
message(FATAL_ERROR "rsync failed (exit code ${rs})")
|
||
endif()
|
||
else()
|
||
message(FATAL_ERROR "Unsupported host platform for asset copying.")
|
||
endif() |